dev-libs/elfutils: new package

1 files changed, 87 insertions, 0 deletions

diff --git a/dev-libs/elfutils/elfutils-0.167.ebuild b/dev-libs/elfutils/elfutils-0.167.ebuild
new file mode 100644
index 000000000..5ae01d793
--- /dev/null
+++ b/dev-libs/elfutils/elfutils-0.167.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools flag-o-matic multilib-minimal
+
+DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
+HOMEPAGE="https://fedorahosted.org/elfutils/"
+SRC_URI="https://fedorahosted.org/releases/e/l/${PN}/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2-with-exceptions"
+SLOT="0"
+KEYWORDS="alpha arm ~arm64 hppa ~mips ppc ppc64 ~sparc64 x86 x86_64"
+IUSE="bzip2 lzma nls static-libs test +threads +utils"
+
+# This pkg does not actually seem to compile currently in a uClibc
+# environment (xrealloc errs), but we need to ensure that glibc never
+# gets pulled in as a dep since this package does not respect virtual/libc
+RDEPEND=">=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	bzip2? ( >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] )
+	lzma? ( >=app-arch/xz-utils-5.0.5-r1[${MULTILIB_USEDEP}] )
+	!dev-libs/libelf
+	!elibc_glibc? (
+		sys-libs/argp-standalone
+		sys-libs/fts-standalone
+		)
+	elibc_musl? ( sys-libs/musl-obstack )
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20130224-r11
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+# We need to require a newer glibc for its elf.h defs. #571814
+DEPEND="${RDEPEND}
+	!<sys-libs/glibc-2.22
+	nls? ( sys-devel/gettext )
+	>=sys-devel/flex-2.5.4a
+	sys-devel/m4"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.118-PaX-support.patch"
+	"${FILESDIR}/${PN}-0.164-fix-uninitialised.patch"
+	"${FILESDIR}/${PN}-0.164-musl-combined.patch"
+	"${FILESDIR}/${PN}-0.167-makefile.patch"
+)
+
+src_prepare() {
+	eapply -p0 ${PATCHES[@]}
+	eapply_user
+	use static-libs || sed -i -e '/^lib_LIBRARIES/s:=.*:=:' -e '/^%.os/s:%.o$::' lib{asm,dw,elf}/Makefile.in
+	sed -i 's:-Werror::' */Makefile.in
+	# some patches touch both configure and configure.ac
+	find -type f -exec touch -r configure {} +
+	cp "${FILESDIR}/error.h" "${S}"/lib/
+	cp "${FILESDIR}/error.h" "${S}"/src/
+	eautoreconf
+}
+
+src_configure() {
+	use test && append-flags -g #407135
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable nls) \
+		$(use_enable threads thread-safety) \
+		--program-prefix="eu-" \
+		--with-zlib \
+		$(use_with bzip2 bzlib) \
+		$(use_with lzma)
+}
+
+multilib_src_test() {
+	env	LD_LIBRARY_PATH="${BUILD_DIR}/libelf:${BUILD_DIR}/libebl:${BUILD_DIR}/libdw:${BUILD_DIR}/libasm" \
+		LC_ALL="C" \
+		emake check || die
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	dodoc NOTES
+	# These build quick, and are needed for most tests, so don't
+	# disable their building when the USE flag is disabled.
+	use utils || rm -rf "${ED}"/usr/bin
+}